Échanger des messages par radio 433 Mhz

Messages radio 433 mhz

Cet article montre comment envoyer et recevoir des messages en utilisant les modules radio 433 mhz. On les trouve sur Ebay pour environ 1 euro (les deux modules !).

RÉCEPTEUR ÉMETTEUR

Il est conseillé de souder sur chaque module une antenne afin d’accroître la portée. L’antenne peut être fabriquée avec du fil rigide. Sa longueur théorique « quart d’onde » est de 173 mm. Dans la pratique une longueur comprise entre 165 mm et 180 mm convient très bien. On peut envoyer des messages de 80 caractères maximum.

Source :

https://www.carnetdumaker.net/articles/communiquer-sans-fil-en-433mhz-avec-la-bibliotheque-virtualwire-et-une-carte-arduino-genuino/

Bibliothèque

http://www.airspayce.com/mikem/arduino/VirtualWire/VirtualWire-1.27.zip

Brochage

Exemple :

On utilise deux Arduino :

– L’un comprend un émetteur 433mhz et un capteur de température et d’humidité DHT11. Il envoie périodiquement les valeurs mesurées.

– L’autre comporte un récepteur 433mhz et envoie sur la console les données reçues.

Programme émetteur

#include <dht1122.h>
#include <gg433mhz.h>

gg433mhz radio;
int numero = 0;

void setup()
{
  radio.startTransmitter(9, 2000); // data sur broche 9, 2000 bauds
}

void sendReleve()
{
  char t[80];
  float temperature, humidite;
  dht1122::readDHT11(8, &temperature, &humidite);
  numero++;
  sprintf(t, "n=%d;t=%d;h=%d;", numero, (int)temperature, (int)humidite);
  radio.sendMessage(t);
}

void loop()
{
  int i;
  sendReleve();
  for (i=0; i < 60; i++) delay(1000);
}

Programme récepteur

#include <gg433mhz.h>

gg433mhz radio;

void setup()
{
  Serial.begin(9600);	
  Serial.println("setup");
  radio.startReceiver(8, 2000); // data sur broche 8, 2000 bauds
  Serial.print("MAX MESSAGE LENGTH ");
  Serial.println(radio.getMaxMessageLength());
}

void loop()
{
  char t[80];
  boolean b;
  b = radio.receiveMessage(t);
  if (b)
  {
    Serial.println(t);
  }
}

Fichier gg433mhz.h

#ifndef __gg433mhz__
#define __gg433mhz__
class gg433mhz
{
 public:
 gg433mhz();
 void startReceiver(byte pin_rx, int bauds);
 int getMaxMessageLength();
 boolean receiveMessage(char msg[]);
 void startTransmitter(byte pin_tx, int bauds);
 void sendMessage(char msg[]);
private:
};
#endif

Fichier gg433mhz.cpp

#include <Arduino.h>
#include <VirtualWire.h>
#include "gg433mhz.h"

gg433mhz::gg433mhz()
{
}

void gg433mhz::startReceiver(byte pin_rx, int bauds)
{
  vw_set_rx_pin(pin_rx);
  vw_set_ptt_inverted(true); // Required for DR3100
  vw_setup(bauds);   // Bits per sec
  vw_rx_start();       // Start the receiver PLL running
}

int gg433mhz::getMaxMessageLength()
{
  return VW_MAX_MESSAGE_LEN;
}

boolean gg433mhz::receiveMessage(char msg[])
{
  uint8_t buf[VW_MAX_MESSAGE_LEN];
  uint8_t buflen = VW_MAX_MESSAGE_LEN;
  int i;
  if (vw_get_message(buf, &buflen) == false)return false; // Non-blocking
  for (i = 0; i < buflen; i++) msg[i] = (char)buf[i];
    msg[buflen] = 0;
    return true;
 }

 void gg433mhz::startTransmitter(byte pin_tx, int bauds)
 {  
  vw_set_tx_pin(pin_tx);
  vw_set_ptt_inverted(true); // Required for DR3100
  vw_setup(bauds);   // Bits per sec
 }

 void gg433mhz::sendMessage(char msg[])
 {
  vw_send((uint8_t *)msg,strlen(msg));
  vw_wait_tx();
 }

Grimeco

Échanger des messages par radio 433 Mhz

Source :

Bibliothèque

Brochage

Exemple :

Programme émetteur

Programme récepteur

Fichier gg433mhz.h

Fichier gg433mhz.cpp

A DECOUVRIR EGALEMENT

Serveur photo avec un ESP32-CAM

Interface USB Arduino Raspberry

Installation du logiciel Arduino sur Raspberry

Laisser un commentaire Annuler la réponse