Aéroports du monde

Le site openflights permet notamment de télécharger un fichier comportant la liste des aéroports du monde.

Le lien pour charger le fichier contenant les aéroports est o p e n f l i g h ts a i r p o r t s

En janvier 2017, la base de données openFlights Airports contient plus de 10 000 aéroports, gares et terminaux de ferry répartis dans le monde entier, comme indiqué sur la carte ci-dessus. Chaque entrée contient les informations suivantes :

00 Id	Identifiant OpenFlights unique pour cet aéroport.
01 Nom	Nom de l’aéroport
02 Ville	Ville principale desservie par l’aéroport.
03 Pays	Pays ou territoire où se trouve l’aéroport.
04 IATA	Code IATA à 3 lettres. Null ou \N s’il n’est pas attribué/inconnu.
05 OACI	Code OACI (ICAO) à 4 lettres. Null ou \N s’il n’est pas attribué.
06 Latitude	Degrés décimaux, généralement à six chiffres significatifs.
07 Longitude	Degrés décimaux, généralement à six chiffres significatifs.
08 Altitude	En pieds.
09 Fuseau horaire	Heures décalées par rapport à UTC.
10 DST	Heure d’été.
11 Fuseau horaire Tz	Fuseau horaire au format « tz » (Olson),
12 Type	Type de l’aéroport.
13 Source	Source de ces données.

Les données sont codées en UTF-8.

Le programme suivant permet de télécharger le fichier airports.dat et de créer un fichier airports.txt comportant les informations suivantes, il permet également d’afficher les n aéroports les plus proches (distance à vol d’oiseau) d’un point spécifié par sa latitude et sa longitude.

Structure du fichier airports.txt

00 nom de l’aéroport
01 nom de la ville la plus proche
02 pays
03 code IATA
04 code ICAO (OACI)
05 latitude
06 longitude
07 altitude

Java

/*!
Source: https://openflights.org/data.html
Fichier airport.dat
00 Airport ID  Unique OpenFlights identifier for this airport.
01 Name  Name of airport. May or may not contain the City name.
02 City  Main city served by airport. May be spelled differently from Name.
03 Country  Country or territory where airport is located. See countries.dat to cross-reference to ISO 3166-1 codes.
04 IATA  3-letter IATA code. Null if not assigned/unknown.
05 ICAO  4-letter ICAO code, Null if not assigned.
06 Latitude  Decimal degrees, usually to six significant digits. Negative is South, positive is North.
07 Longitude  Decimal degrees, usually to six significant digits. Negative is West, positive is East.
08 Altitude  In feet.
09 Timezone  Hours offset from UTC. Fractional hours are expressed as decimals, eg. India is 5.5.
10 DST  Daylight savings time. One of E (Europe), A (US/Canada), S (South America), O (Australia), Z (New Zealand), N (None) or U (Unknown). See also: Help: Time
11 Tz database time zone  Timezone in "tz" (Olson) format, eg. "America/Los_Angeles".
12 Type  Type of the airport. Value "airport" for air terminals, "station" for train stations, "port" for ferry terminals and "unknown" if not known. In airports.csv, only type=airport is included.
13 Source  Source of this data. "OurAirports" for data sourced from OurAirports, "Legacy" for old data not matched to OurAirports (mostly DAFIF), "User" for unverified user contributions. In airports.csv, only source=OurAirports is included.
The data is UTF-8 encoded.

// https://raw.githubusercontent.com/jpatokal/openflights/master/data/airports.dat
*/
proc usage()
   println("aeroports, usage:")
   println("   java aeroports -load : charge le fichier airport.dat")
   println("                          et genere le fichier airports.txt")
   println("   java aeroports latitude longitude n")
   println("            recherche et affiche les informations des n aeroports")
   println("            les plus proches du point specifie par la latitude et la longitude")  
   println("            Exemple: java aeroports 50.3797 3.25722 10")        
   exit()
end proc

func double feetToMeter(double pieds)
/*
 * Convertit un nombre de piers en metres
 *
 */
  return pieds*0.3048
end func

proc loadAirports()exception
   textfile f,fout
   string d,u,r
   boolean b
   lexical lex
   string[] t
   int i
   getInternet("https://raw.githubusercontent.com/jpatokal/openflights/"+
               "master/data/airports.dat","airports.dat")
   open(f,"airports.dat",0)
   open(fout,"airports.txt",1)
   b=readLine(f,d)
   while b
      d=utf8ToString(d)
      d=replace(d,"\\N","?")
      if endsWith(d,",")
         d=d+"?"
      end if   
      start(lex,d,false)
      u=us(lex)
      r=""
      while u!=""
         if getType(lex)=="L"
            u=replace(u,",","$V")
            u=right(u,1)
            u=deleteLastChar(u)
            if u==""
               u="?"
            end if   
         end if
         r=r+u   
         u=us(lex)
      end while
      r=replace(r,",","\t")
      r=replace(r,"$V",",")
      t=getWords(r,"\t")
      if length(t)!=14
         println(itos(length(t))+" "+r)
         println(d)
      end if
      r=""
      i=1
      while i<=7
         r=r+t[i]+"\t"
         i=i+1
      end while 
      r=r+itos(dtoi(feetToMeter(stod(t[8]))))
      println(fout,r)
      b=readLine(f,d)
   end while
   close(f)
   close(fout)
end proc

func double degToRad(double degre)
/*
 * Convertit un nombre de degrees en radians
 * 
 * */
   return degre*0.0174533
end func

func double sphereDist(double lata,double lona,double latb, double lonb)
/*
 * Calcule la distance spherique entre deux points situes sur la terre
 *
 */
   double d,lat1,lon1,lat2,lon2
   lat1=degToRad(lata)
   lon1=degToRad(lona)
   lat2=degToRad(latb)
   lon2=degToRad(lonb)
   d=acos(sin(lat1)*sin(lat2)+cos(lat1)*cos(lat2)*cos(lon1-lon2))
   return d*6378.0
end func
 
func string[] searchNearAirports(double lat,double lon,int nb) exception
   double d
   string w,aeroport
   textfile f
   string[] tw,t
   boolean b
   int i
   stringvector v
   open(f,"airports.txt",0)
   b=readLine(f,w)
   while b
      tw=getWords(w,"\t")
      d=sphereDist(lat,lon,stod(tw[5]),stod(tw[6]))
      add(v,padIntZeroLeft(dtoi(d),5)+"\t"+w)
      b=readLine(f,w)
   end while
   close(f)
   tw=vtos(v)
   sort(tw)
   dim t[nb]
   for i while i<nb
      t[i]=tw[i]
   end for
   return t
end func

proc demarrer()exception
   string param
   param=argGet(0)
   if param==""
      usage()
   end if
   switch
   case param=="-load"
      loadAirports()
   case argCount()==3
      print(searchNearAirports(stod(param),stod(argGet(1)),stoi(argGet(2))))    
   default
      usage()
   end switch
end proc
//— MAIN —————–
try
   demarrer()
catch
   println(exceptionToString())
end catch

Exemples d’exécution:

java aeroports -load

java aeroports 50.38 3.28 10
0  00014   Valenciennes-Denain Airport     Valenciennes    France  XVS     LFAV    50.325801849365234      3.4612600803375244      53
1       00019   Cambrai-Épinoy (BA 103) Air Base        Cambrai France  ?       LFQI    50.221802       3.15424 78
2       00024   Lille-Lesquin Airport   Lille   France  LIL     LFQQ    50.563332       3.086886        47
3       00037   Lille/Marcq-en-Baroeul Airport  Marcq En Baroeul        France  ?       LFQO    50.687198638916016      3.0755600929260254      21
4       00044   Chièvres Air Base       Chievres        Belgium ?       EBCV    50.575801849365234      3.8310000896453857      59
5       00048   Wevelgem Airport        Kortrijk-vevelgem       Belgium KJK     EBKT    50.817199707    3.20472002029   19
6       00052   Merville-Calonne Airport        Merville        France  HZB     LFQT    50.61840057373047       2.642240047454834       18
7       00054   Maubeuge-Élesmes Airport        Maubeuge        France  XME     LFQJ    50.31050109863281       4.033120155334473       137
8       00059   Péronne-Saint-Quentin Airport   Peronne France  ?       LFAG    49.8685 3.02958 89
9       00061   Albert-Bray Airport     Albert  France  BYF     LFAQ    49.9715003967   2.69765996933   110

Grimeco

Aéroports du monde

A DECOUVRIR EGALEMENT

Localités du monde

Laisser un commentaire Annuler la réponse