Station météo

Projet station météo – 4 – Enregistrement des données

Par geo le vendredi, juin 10, 2022

Cette étape fait une synthèse des 3 étapes précédentes et a pour but principal d’enregistrer de façon périodique les données météo recueillies depuis la station extérieur Bresser ainsi que la pression atmosphérique obtenue sur le web. Les données sont stockées à l’aide d’une « table sql ». Les colonnes de cette table sont:

s : aaaammjjhh : stamp du relevé Bresser
t : double : température
h : int : humidité
wd : int : direction du vent en degrés
ws : double : vitesse moyenne du vent en m/s
wg : double : vitesse maximum du vent en m/s (rafale)
r : double : cumul de précipitations en mm
sp : aaaammjjhh : stamp du relevé Web pour la pression atmosphérique sous la forme aaaammjjhhss
p : int : pression atmosphérique en hectoPascal (hPa)

Le programme de « log » (enregistrement des données) permet de stocker les données toutes les 30 minutes en utilisant un gestionnaire de taches du langage Basilic .

Programme

Java

taskmanager tm
string icao,bdd

proc p(string d)
   print(d)
end proc

proc pl(string d)
   p(d)
   p("\n")
end proc

proc usage()
   pl("stationmeteo, usage:")
   pl("   java stationmeteo icao")
   pl("        ou icao est le code icao le plus proche du lieu de residence")
   exit()
end proc

proc errex()
   pl(exceptionToMessage())
end proc

func string[] capture()exception
   executerCmd("rtl_433 -f 868M -E")
   return getFileArray("stdout.txt")
end func

proc analyseCapture(stringhashmap h)exception
   string w
   string[] t
   int i,n,k
   t=capture()
   n=length(t)
   for i while i<n
      k=indexOf(t[i],":")
      if k!=-1
         put(h,trim(left(t[i],k)),trim(right(t[i],k+1)))
      end if
   end for
end proc

func string getBresser()exception
   stringhashmap h
   string p
   string[][] t 
   int i,n
   analyseCapture(h)
   analyseCapture(h)
   t=getHashmap(h)
   n=length(t)
   p=""
   for i while i<n
      p=p+t[i][0]+"="+t[i][1]+";"
   end for
   return p
end func

func string repAll(string d,string chars)
   string r,c
   int i,n
   r=""
   n=size(d)
   for i while i<n
      c=charAt(d,i)
      if indexOf(chars,c)==-1
         r=r+c
      end if
   end for
   return r
end func

func string getBresser5In1()exception
   string r,d,w
   d=getBresser()
   r=""
   r=r+substring(repAll(stringProperty(d,"time"),"-: "),0,12)+"\t"
   r=r+repAll(stringProperty(d,"Temperature")," C")+"\t"
   r=r+stringProperty(d,"Humidity")+"\t"
   r=r+stringProperty(d,"Direction")+"\t"
   r=r+repAll(stringProperty(d,"Wind Speed")," m/s")+"\t"
   r=r+repAll(stringProperty(d,"Wind Gust")," m/s")+"\t"
   r=r+repAll(stringProperty(d,"Rain")," m")+"\t"
   return r
end func

func string getHpa(string icao)exception
   string w,r,datJour
   string[] t,tw
   int i,n,j,k
   r=""
   getInternet("https://www.aviationweather.gov/metar/data?ids="+icao+
               "&format=raw&hours=0&taf=off&layout=off","metar.txt")
   w=getFileString("metar.txt")
   java
      // expression reguliere pour supprimer les tags html
      w.val=w.val.replaceAll("\\<.*?>","");
   end java
   putFileString("metar1.txt",w)
   t=getFileArray("metar1.txt")
   n=length(t)
   for i while i<n
      w=toLowerCase(trim(t[i]))
      if startsWith(w,icao)
         tw=getWords(w," ")
         k=length(tw)
         for j while j<k
            if startsWith(tw[j],"q")
               r=r+"p="+right(tw[j],1)+";"
            end if
            if endsWith(tw[j],"z")
               datJour=getDateJour()
               r=r+"dt="+substring(datJour,6,6+4)+substring(datJour,3,3+2)+
                 substring(tw[j],0,0+6)+";" 
            end if
         end for
      end if
   end for
   return stringProperty(r,"dt")+"\t"+stringProperty(r,"p")+"\t"
end func

proc tacheMeteo()
   string bresser,pression,w
   string[] tw
   int i,n,nbretry
   pl(stampToString(stamp())+" Tache meteo")
   try
      nbretry=5
      n=0
      pression=deleteLastChar(getHpa(icao))
      bresser=getBresser5In1()
      w="["+replace(bresser+pression,"\t","|")+"]"
      while indexOf(w,"?")!=-1 and n<=nbretry
         n=n+1
         pl("retry "+itos(n)+" "+w)
         bresser=getBresser5In1()
      end while
      pl("        "+w)
      w="insert into "+icao+" values("
      tw=getWords(bresser+pression,"\t")
      n=length(tw)
      for i while i<n
         w=w+"'"+tw[i]+"'"
         if i<n-1
            w=w+","
         end if
      end for
      w=w+")"
      debugSql(bdd,w,true,"logbressericao.txt")
   catch
      errex()
    end catch  
end proc

proc demarrer() exception
   icao=argGet(0)
   if icao==""
      usage()
   end if
   bdd="bddlogbressericao"
   mkdir(bdd)
   debugSql(bdd,"create table "+icao+"(s,t,h,wd,ws,wg,r,sp,p)",true,"logbressericao.txt")
   addTaskPeriodic(tm,"id1","proc","tacheMeteo",1000*60*30)// 30 minutes
end proc
//— MAIN —
try
   demarrer()
catch
    errex()
end catch

Exemple de trace à l’exécution:

-----------------------------------------------------
Ven 10/06/2022 06:04:05 Tache meteo
        [202206100604|16.6|74|102|1.0|1.0|64.8|202206100400|1020]
insert into lfqq values('202206100604','16.6','74','102','1.0','1.0','64.8','202206100400','1020')
Duree 00 h 00 m 00 s 012 ms
Retcode OK
-----------------------------------------------------
Ven 10/06/2022 06:34:05 Tache meteo
        [202206100634|16.5|75|216|0.8|0.8|64.8|202206100430|1020]
insert into lfqq values('202206100634','16.5','75','216','0.8','0.8','64.8','202206100430','1020')
Duree 00 h 00 m 00 s 013 ms
Retcode OK
-----------------------------------------------------
Ven 10/06/2022 07:04:05 Tache meteo
        [202206100704|16.7|75|258|1.0|1.0|64.8|202206100500|1021]
insert into lfqq values('202206100704','16.7','75','258','1.0','1.0','64.8','202206100500','1021')
Duree 00 h 00 m 00 s 015 ms
Retcode OK
-----------------------------------------------------

Exemple de contenu de la table

202206100204	16.0	74	204	0.0	0.0	64.8	202206100000	1020
202206100234	16.1	74	240	0.0	0.0	64.8	202206100030	1020
202206100304	16.2	72	132	0.6	0.6	64.8	202206100100	1020
202206100334	16.2	74	240	0.0	0.0	64.8	202206100130	1020
202206100404	16.2	74	162	0.0	0.0	64.8	202206100200	1020
202206100434	16.4	73	252	0.0	0.0	64.8	202206100230	1020
202206100504	16.2	75	216	0.0	0.0	64.8	202206100300	1020
202206100534	16.5	73	216	1.0	1.0	64.8	202206100330	1020
202206100604	16.6	74	102	1.0	1.0	64.8	202206100400	1020
202206100634	16.5	75	216	0.8	0.8	64.8	202206100430	1020
202206100704	16.7	75	258	1.0	1.0	64.8	202206100500	1021

basilic bresser data log météo raspberry station

Laisser un commentaire Annuler la réponse