Serveur photo avec un ESP32-CAM

Cet article décrit l’utilisation d’un esp32-cam pour réaliser un serveur web affichant l’image courante. Le principe d’acquisition consiste à faire une requête HTTP sur l’url de l’esp32. Exemple, si dans un réseau local, l’esp32 a pour IP 192.168.1.30 faire la requête:

http://192.168.1.30

Le matériel

Caractéristiques:

Alimentation: 3,3 ou 5 Vcc
Consommation: 2000 mA maxi
Microcontrôleur: ESP32 à 240 MHz
Mémoire RAM: 520 Ko
Mémoire PSRAM: 4 Mo
Compatibilité: capteurs OV2640 et OV7670 (capteur OV2640 intégré)
Interfaces sans fil:
– Bluetooth: compatible 4.2, EDR et BLE
– WiFi 802.11b/g/n/e/i (compatible WPA, WPA2, WPA2-Enterprise et WPS)
Interfaces disponibles: UART, SPI, I2C, PWM, ADC et DAC
Formats vidéo supportés: JPEG (OV2640)
Débit série: 115200 bps
Lecteur de carte micro-SD (4 Go maxi, carte non inclus)
Broches utilisées par le lecteur micro-SD: 2, 4, 12, 13, 14 et 15
Sorties 3,3 Vcc
Broches GPIO: UART, SPI et I2C
Bouton reset
Température de service: -20 à 85 °C
Dimensions: 27 x 40 x 4,5 mm
Poids: 10 g

Pour le développement et l’utilisation, il est recommandé d’utiliser le programmateur ESP-32-CAM. Cela permet d’utiliser un câble usb (faire bien attention au modèle de programmateur) pour alimenter et faire le développement

En avril 2024, les modules ESP32-CAM et le programmateur peuvent être achetés pour un prix TTC respectivement de l’ordre de 15 € et 3 €

Logiciel

On utilise le système de développement Arduino en installant la bibliothèque pour les cartes esp32 de Espressif:

Le programme réalisé utilise la Sdcard pour stocker un fichier texte config.ini comportant 5 lignes pour pouvoir configurer la caméra au boot. Les différentes lignes sont:

ssid : nom du réseau wifi pour se connecter
passwd : mot de passe pour se connecter au réseau wifi
framesize : dimensions de l’image capturée
hmirror : miroir horizontal
vflip : miroir vertical

Exemple de contenu:

Plain Text

monidentifiantreseau
monmotdepassereseau
9
0
1

La ligne 3 permet de définir les dimensions de l’image:

Plain Text

CODE                         RESOLUTION
 0    FRAMESIZE_96X96,    // 96×96
 1    FRAMESIZE_QQVGA,    // 160×120
 2    FRAMESIZE_QCIF,     // 176×144
 3    FRAMESIZE_HQVGA,    // 240×176
 4    FRAMESIZE_240X240,  // 240×240
 5    FRAMESIZE_QVGA,     // 320×240
 6    FRAMESIZE_CIF,      // 400×296
 7    FRAMESIZE_HVGA,     // 480×320
 8    FRAMESIZE_VGA,      // 640×480
 9    FRAMESIZE_SVGA,     // 800×600
10    FRAMESIZE_XGA,      // 1024×768
11    FRAMESIZE_HD,       // 1280×720
12    FRAMESIZE_SXGA,     // 1280×1024
13    FRAMESIZE_UXGA,     // 1600×1200

Ainsi sur l’exemple précédent le code 9 signifie que l’on sélectionne la résolution SVGA (800×600)

La ligne 4 définit si on veut faire un miroir horizontal (0 pour non, 1 pour oui)

La ligne 5 définit si on veut faire un miroir vertical (0 pour non, 1 pour oui)

Enfin la SD-Card est également utilisée pour stocker la dernière image capturée sous le nom capture.jpg

Code Source:

#include <esp_camera.h>
#include <SD.h>
#include <WiFi.h>
#include <WebServer.h>

#define MAX_STRING_32 32
typedef char string32[MAX_STRING_32];

#define PWDN_GPIO_NUM 32
#define RESET_GPIO_NUM -1
#define XCLK_GPIO_NUM 0
#define SIOD_GPIO_NUM 26
#define SIOC_GPIO_NUM 27

#define Y9_GPIO_NUM 35
#define Y8_GPIO_NUM 34
#define Y7_GPIO_NUM 39
#define Y6_GPIO_NUM 36
#define Y5_GPIO_NUM 21
#define Y4_GPIO_NUM 19
#define Y3_GPIO_NUM 18
#define Y2_GPIO_NUM 5
#define VSYNC_GPIO_NUM 25
#define HREF_GPIO_NUM 23
#define PCLK_GPIO_NUM 22

// Variables globales ———————

string32 ssid,password;
int framesize, hmirror, vflip;
SPIClass hspi_G(HSPI);
WebServer server(80);
File fconfig;

// Procedures et fonctions —————

int initSD() {
#define CLK 14
#define MISO 2
#define MOSI 15
#define CS 13
  hspi_G.begin(CLK, MISO, MOSI, CS);
  return SD.begin(CS, hspi_G, 80000000);
}

void getConfigStr(string32 r) {
  int i, n;
  n = fconfig.readBytesUntil('\n', r, MAX_STRING_32);
  r[n] = 0;
  for (i = 0; i < n; i++)
    if (r[i] < 32) r[i] = 0;
}

int getConfigInt() {
  string32 w;
  getConfigStr(w);
  return atoi(w);
}

void analyseConfig() {
  fconfig = SD.open("/config.ini");
  if (fconfig) {
    getConfigStr(ssid);
    getConfigStr(password);
    framesize = getConfigInt();
    hmirror = getConfigInt();
    vflip = getConfigInt();
    fconfig.close();
  } else {
    Serial.println("Erreur lors de l'ouverture du fichier config.ini");
  }
}

void setup() {
  Serial.begin(115200);
  // Initialisation de la SD Card
  if (!initSD()) Serial.println("SD Card ERROR");
  else Serial.println("SD Card OK");
  analyseConfig();
  // Wi-Fi connection
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("SSID ");
  Serial.print(ssid);
  Serial.print(" IP ");
  Serial.println(WiFi.localIP());
  // Initialisation de la caméra
  camera_config_t config;
  config.ledc_channel = LEDC_CHANNEL_0;
  config.ledc_timer = LEDC_TIMER_0;
  config.pin_d0 = Y2_GPIO_NUM;
  config.pin_d1 = Y3_GPIO_NUM;
  config.pin_d2 = Y4_GPIO_NUM;
  config.pin_d3 = Y5_GPIO_NUM;
  config.pin_d4 = Y6_GPIO_NUM;
  config.pin_d5 = Y7_GPIO_NUM;
  config.pin_d6 = Y8_GPIO_NUM;
  config.pin_d7 = Y9_GPIO_NUM;
  config.pin_xclk = XCLK_GPIO_NUM;
  config.pin_pclk = PCLK_GPIO_NUM;
  config.pin_vsync = VSYNC_GPIO_NUM;
  config.pin_href = HREF_GPIO_NUM;
  config.pin_sscb_sda = SIOD_GPIO_NUM;
  config.pin_sscb_scl = SIOC_GPIO_NUM;
  config.pin_pwdn = PWDN_GPIO_NUM;
  config.pin_reset = RESET_GPIO_NUM;
  config.xclk_freq_hz = 20000000;
  config.pixel_format = PIXFORMAT_JPEG;
  /*
 0    FRAMESIZE_96X96,    // 96×96
 1    FRAMESIZE_QQVGA,    // 160×120
 2    FRAMESIZE_QCIF,     // 176×144
 3    FRAMESIZE_HQVGA,    // 240×176
 4    FRAMESIZE_240X240,  // 240×240
 5    FRAMESIZE_QVGA,     // 320×240
 6    FRAMESIZE_CIF,      // 400×296
 7    FRAMESIZE_HVGA,     // 480×320
 8    FRAMESIZE_VGA,      // 640×480
 9    FRAMESIZE_SVGA,     // 800×600
10    FRAMESIZE_XGA,      // 1024×768
11    FRAMESIZE_HD,       // 1280×720
12    FRAMESIZE_SXGA,     // 1280×1024
13    FRAMESIZE_UXGA,     // 1600×1200
*/
  config.frame_size = (framesize_t)framesize;
  config.jpeg_quality = 10;
  config.fb_count = 2;
  // Initialisation de la camera
  esp_err_t err = esp_camera_init(&config);
  if (err != ESP_OK) {
    Serial.printf("Erreur lors de l'initialisation de la caméra (%d)\n", err);
    return;
  }
  Serial.print("Resolution ");
  Serial.println(config.frame_size);
  Serial.println("Camera prete.");
  // Configuration de la camera
  sensor_t* s = esp_camera_sensor_get();
  s->set_brightness(s, 0);                  // -2 to 2
  s->set_contrast(s, 0);                    // -2 to 2
  s->set_saturation(s, 0);                  // -2 to 2
  s->set_special_effect(s, 0);              // 0 to 6 (0 – No Effect, 1 – Negative, 2 – Grayscale, 3 – Red Tint, 4 – Green Tint, 5 – Blue Tint, 6 – Sepia)
  s->set_whitebal(s, 1);                    // 0 = disable , 1 = enable
  s->set_awb_gain(s, 1);                    // 0 = disable , 1 = enable
  s->set_wb_mode(s, 0);                     // 0 to 4 – if awb_gain enabled (0 – Auto, 1 – Sunny, 2 – Cloudy, 3 – Office, 4 – Home)
  s->set_exposure_ctrl(s, 1);               // 0 = disable , 1 = enable
  s->set_aec2(s, 0);                        // 0 = disable , 1 = enable
  s->set_ae_level(s, 0);                    // -2 to 2
  s->set_aec_value(s, 300);                 // 0 to 1200
  s->set_gain_ctrl(s, 1);                   // 0 = disable , 1 = enable
  s->set_agc_gain(s, 0);                    // 0 to 30
  s->set_gainceiling(s, (gainceiling_t)0);  // 0 to 6
  s->set_bpc(s, 0);                         // 0 = disable , 1 = enable
  s->set_wpc(s, 1);                         // 0 = disable , 1 = enable
  s->set_raw_gma(s, 1);                     // 0 = disable , 1 = enable
  s->set_lenc(s, 1);                        // 0 = disable , 1 = enable
  s->set_hmirror(s, hmirror);               // 0 = disable , 1 = enable
  s->set_vflip(s, vflip);                   // 0 = disable , 1 = enable
  s->set_dcw(s, 1);                         // 0 = disable , 1 = enable
  s->set_colorbar(s, 0);                    // 0 = disable , 1 = enable
  // Serveur web
  server.on("/", HTTP_GET, handleRoot);
  server.begin();
  Serial.println("Serveur web demarre");
}

void handleRoot() {
  Serial.println("Requête HTTP reçue");
  // Capture d'une nouvelle image
  camera_fb_t* fb;
  File file;
  for (int i = 0; i < 5; i++) {
    if (fb != NULL) esp_camera_fb_return(fb);
    fb = esp_camera_fb_get();
    if (!fb) {
      Serial.println("Erreur lors de la capture de l'image");
      server.send(500, "text/plain", "Erreur lors de la capture de l'image");
      return;
    }
    file = SD.open("/capture.jpg", FILE_WRITE);
    if (!file) {
      Serial.println("Erreur lors de l'ouverture du fichier sur la carte SD");
    } else {
      file.write(fb->buf, fb->len);
      file.close();
    }
  }
  // Liberation de la memoire utilisee pour l'image capturee
  esp_camera_fb_return(fb);
  // Envoi du fichier capture.jpg
  file = SD.open("/capture.jpg", FILE_READ);
  if (!file) {
    Serial.println("Erreur: Impossible d'ouvrir le fichier capture.jpg");
    server.send(500, "text/plain", "Erreur interne du serveur");
    return;
  }
  server.streamFile(file, "image/jpeg");
  file.close();
}

void loop() {
  server.handleClient();
}

Grimeco

Serveur photo avec un ESP32-CAM

Le matériel

Caractéristiques:

Logiciel

Code Source:

A DECOUVRIR EGALEMENT

Interface USB Arduino Raspberry

Installation du logiciel Arduino sur Raspberry

Mini oscilloscope Oled

Laisser un commentaire Annuler la réponse