Projet station météo – 5 – Statistiques

Ce billet est le prolongement du billet précédant ( Projet station météo – 4 – Enregistrement des données). L’application présentée permet d’illustrer graphiquement la situation météo des 31 derniers jours. L’application s’exécute en mode console, il faut fournir deux paramètres le nom icao de la station et le nom de la localité. L’application utilise les données situées dans le répertoire « bddlogbressericao » ( voir Projet station météo – 4 – )

Exemple d’appel:

java statbressericao lfqq Rieulay

Résultat : fichier lfqq.jpg

Programme statbressericao.bcj

Java

string bdd,icao,localite

proc p(string d)
   print(d)
end proc

proc pl(string d)
   p(d)
   p("\n")
end proc

proc usage()
   pl("statbressericao, usage:")
   pl("   java statbressericao icao localite")
   pl("        icao est le nom de la table log")
   pl("        localite est le nom du lieu sur le fichier image resultat")
   pl("    Resultat : fichier image icao.jpg")
   pl("    Exemple:")
   pl("    java statbressericao lfqq douai")
   pl("         a pour resultat le fichier douai.jpg")
   exit()          
end proc

proc echelleTemps(graphique g,string[][] t,int hauteur,int r,int v,int b)
   string w,memj,j
   int i,n
   n=length(t)
   setColor(g,r,v,b)
   for i while i<n
      j=substring(t[i][0],6,6+2)
      if memj!=j
         drawString(g,j,i+1,15)
         drawLine(g,i,0,i,hauteur-80)
      end if
      memj=j
   end for
end proc

func int genLig(double valeur,int hauteur,int decalLigne,double coef,double pointzero)
   return hauteur-decalLigne-dtoi((valeur-pointzero)*coef)
end func

proc genMesure(graphique g,string[][] t,int largeur,int hauteur,
   int col,int decalLigne,int r,int v,int b,double coef,double pointzero)
   int i,n
   n=length(t)
   setColor(g,r,v,b)
   for i while i<n-1
      if indexOf(t[i][col],"?")==-1 and indexOf(t[i+1][col],"?")==-1 
         drawLine(g,
         i,genLig(stod(t[i][col]),hauteur,decalLigne,coef,pointzero),
         i+1,genLig(stod(t[i+1][col]),hauteur,decalLigne,coef,pointzero))
      end if
   end for
end proc

proc drawHorPointille(graphique g,int largeur,int hauteur,double valeur,
   int decalLigne,int r,int v,int b,double coef,double pointzero,double coefval,string unite)
   int i,k
   k=genLig(valeur,hauteur,decalLigne,coef,pointzero)
   setColor(g,r,v,b)
   drawString(g,itos(dtoi(valeur*coefval))+" "+unite,1,k)
   for i while i<largeur
      if i%10==0
         drawLine(g,i+5,k,i,k)
      end if
   end for
end proc

func int dirVentToNum8Dir(int d)
/*
Retourne 0  1  2  3  4  5  6  7  -1
Pour     S  SO O  NO N  NE E  SE ? 
*/
   int r
   double x,mini,maxi
   int i
   if d==-1
      return -1
   end if   
   x=itod(d%360)
   r=-1
   for i while i<9 and r==-1
      mini=-22.5+itod(i)*45.0
      maxi=mini+45.0
      if x>=mini and x<=maxi
         r=(i+4)%8
      end if
   end for
   return r
end func

func string dirVentToString8Dir(int d)
  int n
  string[] t
  n=dirVentToNum8Dir(d)
  if n==-1
     return "?"
  end if   
  t=getWords("S,SO,O,NO,N,NE,E,SE",",")
  return t[n]
end func

func double degToRad(double d)
   return d*0.0174533
end func

proc genTriangle(graphique g,int angle,double[] tcol,double[] tlig,string indices,int dx,int dy,int r,int v,int b)
   int i,k
   string[] tw
   int[] tx,ty
   double a,x,y
   dim tx[3]
   dim ty[3]
   a=degToRad(itod(angle))
   tw=getWords(indices,",")
   for i while i<3
      k=stoi(tw[i])
      tx[i]=dx+dtoi(tcol[k]*cos(a)+tlig[k]*sin(a))
      ty[i]=dy+dtoi(-tcol[k]*sin(a)+tlig[k]*cos(a))
   end for
   setColor(g,r,v,b)
   fillPolygon(g,tx,ty)
end proc

proc dessinerGirouette(graphique g,int col,int lig,double rayon,int direction)
   double[] tcol,tlig
   double delta
   delta=rayon*cos(45.0)
   dim tcol[4]
   dim tlig[4]
   tcol[0]=0.0          tlig[0]=-rayon
   tcol[1]=delta        tlig[1]=delta
   tcol[2]=-delta       tlig[2]=delta
   tcol[3]=0.0          tlig[3]=rayon/4.0
   genTriangle(g,direction,tcol,tlig,"2,0,3",col,lig,0,255,0)
   genTriangle(g,direction,tcol,tlig,"3,0,1",col,lig,0,128,0)
end proc

proc genDirVent(graphique g,string[][] t)
   string w,memj,j,dir,val
   string[][] tr
   int i,n,memcol,somdir,nbdir
   n=length(t)
   memcol=1
   somdir=0
   nbdir=0
   for i while i<n
      j=substring(t[i][0],6,6+2)
      if memj!=j or i==n-1
         if nbdir!=0
            somdir=somdir/nbdir
         else
            somdir=-1
         end if       
         try
           //pl("Nb mesures "+itos(nbdir)+" Dir vent "+itos(somdir)+" "+itos(dirVentToNum8Dir(somdir))+
           //" "+dirVentToString8Dir(somdir))
           dessinerGirouette(g,memcol+24,380,16.0,180-somdir)
            drawString(g,dirVentToString8Dir(somdir),memcol+16,400)
         catch
         end catch
         somdir=0
         nbdir=0
         memcol=i+1
      end if
      dir=t[i][3]
      if dir!="?"
         somdir=somdir+stoi(dir)
         nbdir=nbdir+1
      end if
      memj=j
   end for
end proc

func string padRight(string d,int max,string car)
   string r
   r=d
   while size(r)<max
      r=r+car
   end while
   return r
end func

func string[] moyMinMaxCol(string[][] t,int col,double coef)
   int somme,i,n,mini,maxi,v
   string[] r
   dim r[3]
   mini=9999999
   maxi=-9999999
   n=length(t)
   somme=0
   for i while i<n
      if indexOf(t[i][col],"?")==-1
         v=dtoi(stod(t[i][col])*coef)
         somme=somme+v
         if v<mini
            mini=v
         end if
         if v>maxi
            maxi=v
         end if
      end if
   end for
   r[0]=itos(somme/n)
   r[1]=itos(mini)
   r[2]=itos(maxi)
   return r
end func

func string genMMM(string[][] tt,int col,string libelle,string unite,double coef)
   string[] t
   string r
   t=moyMinMaxCol(tt,col,coef)
   r=padRight(libelle+" ("+unite+")",15," ")+padRight(t[0],5," ")
   +padRight(t[1],5," ")+padRight(t[2],5," ")
   return r
end func

proc drawLegende(graphique g,string texte,int col,int lig,int r,int v,int b)
   setColor(g,r,v,b)
   drawLine(g,col,lig-5,col+20,lig-5)
   drawString(g,texte,col+25,lig)
end proc

proc genStat(graphique g,string[][] t,string stampRacine)
   string w,annee
   int n,d,i
   try
      setFont(g,"name=monospaced;style=g;size=14")
   catch
   end catch
   n=14
   d=448
   setColor(g,0,0,255)
   w=padRight(" ",15," ")+padRight("Moy",5," ")+padRight("Min",5," ")+padRight("Max",5," ")
   drawString(g,w,1,d+n*0)
   w=genMMM(t,1,"Temp","°C",1.0)
   drawString(g,w,1,d+n*1)
   w=genMMM(t,5,"Vent","km/h",3.6)// cv m/s en km/h
   drawString(g,w,1,d+n*2)
   w=genMMM(t,8,"Pression","hPa",1.0)
   drawString(g,w,1,d+n*3)
   w=genMMM(t,2,"Humidite","%",1.0)
   drawString(g,w,1,d+n*4)
   try
      setFont(g,"name=monospaced;style=g;size=20")
   catch
   end catch
   annee=left(stampRacine,4)
   w=getNomMois("01/"+substring(stampRacine,4,4+2)+"/"+annee)+" "+annee
   setColor(g,0,0,0)
   drawString(g,w,300,d+30)
   drawLegende(g,"Température:°C",500,d+60,0,0,255)
   drawLegende(g,"Pression:hPa",700,d+60,255,0,0)
   drawLegende(g,"Vent:km/h",875,d+60,0,255,0)
   drawLegende(g,"Cumul pluie:mm",1025,d+60,0,255,255)
   // dernier relevé
   n=length(t)-1
   w=localite+" "+stampToString(t[n][0]+"00000")
   w=left(w,lastIndexOf(w,":"))
   w=w+" T="+t[n][1]+"°C H="+t[n][2]+"%"+" P="+t[n][8]+" hPa"
   setColor(g,0,0,255)
   drawString(g,w,500,d+30)
end proc

proc genPluie(graphique g,string[][] t)exception
   int i,n,memcol
   string j,memj
   double memp,p,cumul,delta
   memp=0.0
   n=length(t)
   memj=""
   cumul=0.0
   memcol=1
   for i while i<n
      p=stod(t[i][6])
      if p>=memp
         delta=p-memp
         cumul=cumul+delta
       //  pl("delta mm "+dtos(delta))
         j=substring(t[i][0],6,6+2)
         if i>=1 and (memj!=j or i==n-1 )
            //pl("cumul mm "+stampToString(t[i-1][0]+"00000")+" "+itos(dtoi(cumul+0.5)))
            setColor(g,0,255,255)
            fillRect(g,memcol+9,200-dtoi(cumul+0.5)*2,30,dtoi(cumul+0.5)*2)
            setColor(g,0,0,0)
            drawString(g,itos(dtoi(cumul+0.5)),memcol+20,200)
            memcol=i+1
            cumul=0.0
         end if
         memj=j
         memp=p
      end if
   end for
end proc

proc genGraphique(string[][] t,string stampRacine)exception
   graphique g
   int i,n,w,h
   n=length(t)
   w=24*2*31 // 24 h, 2 releves par heure, 31 jours
   h=512
   create(g,w,h)
   setStroke(g,2)
   setColor(g,255,255,255)
   fillRect(g,0,0,w,h)
   echelleTemps(g,t,h,0,0,255)
   // Temperature
   //                    col de t decal ligne r   g   b   zoom
   genMesure(g,t,w,h,    1,       350,        0,  0,  255,4.0,0.0) // temp
   drawHorPointille(g,w,h,0.0,350,0,0,255,4.0,0.0,1.0," °C")
   drawHorPointille(g,w,h,20.0,350,0,0,255,4.0,0.0,1.0," °C")
   drawHorPointille(g,w,h,-10.0,350,0,0,255,4.0,0.0,1.0," °C")
   // Humidite
   //genMesure(g,t,w,h,    2,       300,        0,  255,  255,1.0,0.1)
   //drawHorPointille(g,w,h,80.0,300,0,255,255,1.0,1.0,1.0," %") 
   // Pression
   genMesure(g,t,w,h,    8,       250,        255,  0,  0,3.0,1013.0)
   drawHorPointille(g,w,h,1013.0,250,255,0,0,3.0,1013.0,1.0," hPa")
   // Vent
   genMesure(g,t,w,h,    5,       150,        0,  255,  0,4.0,0.0)
   drawHorPointille(g,w,h,30.0/3.6,150,0,255,0,4.0,0.0,3.6," km/h")
   drawHorPointille(g,w,h,0.0,150,0,255,0,4.0,0.0,3.6," km/h")
   // Dir vent
   genDirVent(g,t)
   genPluie(g,t)
   genStat(g,t,stampRacine)
   //—
   save(g,icao+".jpg")
end proc

proc cmdStatLast()exception
   string ret
   int i,j,n,nblig,nbcol
   string[] tt,tw
   string[][] tr
   ret=runSql(bdd,"select * from "+icao,true,"tmpcbi1.txt")
   tt=getFileArray("tmpcbi1.txt")
   n=length(tt)
   if n<1488 // 31 jours * 24 h * 2 releves par heure
      nblig=n
   else
      nblig=1488
   end if   
   tw=getWords(getFileString(bdd+"/"+icao+".des"),"\t")
   nbcol=length(tw)
   dim tr[nblig][nbcol]
   i=nblig-1
   while i>=0
      tw=getWords(tt[i],"\t")
      for j while j<nbcol
         if j==4 or j==5 // cv m/s en km/h
            tr[i][j]=itos(dtoi(stod(tw[j])*3.6))
         else
            tr[i][j]=tw[j]
         end if   
      end for
      i=i-1
   end while
   genGraphique(tr,stamp())
end proc

proc demarrer()exception
   icao=argGet(0)
   localite=argGet(1)
   if icao=="" or localite==""
      usage()
   end if
   bdd="bddlogbressericao"
   if existsFile(bdd+"/"+icao+".des")==false
      pl("Table "+icao+" non trouvee")
      usage()
   end if
   cmdStatLast()
end proc

//— MAIN —————–

try
   demarrer()
catch
   println(exceptionToString())
end catch

Grimeco

Projet station météo – 5 – Statistiques

Laisser un commentaire Annuler la réponse